Function AddUserToFolder(byref oFolder, byval oUserID, byval oUserName, byref objSession)

        '*********************************************
        ' oFolder                    Public Folder object
        ' oUserID                    EntryID of the user (from the GAL) 
        ' oUserName                Name of the user (from the GAL)
        ' objSession                Session object
        '*********************************************
	Dim sTempUsername
	sTempUsername = ""
	Set objACL = CreateObject("MSExchange.aclobject")
	objACL.CDOItem = oFolder
	Set objFolderACEs = objACL.ACEs
	
	' delete the user if they exist already
	For each objFolderACE in objFolderACes
		sTempUsername = GetACLEntryName(objSession, objFolderACE.ID)
		if sTempUsername = oUserName then
			Log "Deleting User : " & sTempUsername
			objFolderACEs.Delete objFolderACE.ID
		end if
	next
	
	' add user if they did not exist
	Log "Adding user : " & oUserName
	Set objNewACE = CreateObject("MSExchange.ACE")
	objNewACE.ID = oUserID
	objNewACE.Rights = "&H7FB"
	objFolderACEs.Add objNewACE
	objACL.Update
	
	if err then
		AddUserToFolder = false
	else
		AddUserToFolder = true
	end if
	
	Set objACL = nothing
	Set objNewACE = nothing
	Set objFolderACEs = nothing
 	
End Function


Function GetACLEntryName(byref objSession, byval oACLEntryID)
	
        '*********************************************
        ' objSession                Session object
        ' oACLEntryID              EntryID from the folders' ACL
        '*********************************************
	Dim sResult
	sResult = ""
	Select Case oACLEntryId
		Case UDefault 
			sResult = "Default" & vbTAB & "Default"
		Case UAnonymous 
			sResult = "Anonymous" & vbTAB & "Anonymous"
		Case Else
			sResult = objSession.GetAddressEntryFromID(oACLEntryID).Name
			
	End Select
	GetACLEntryName = sResult
	
End Function